[lindachan]

#post-id: 3083-12-43
#original-date: 3.01.2009 Sat
#original-time: 12:43 PM
#original-day:  3083
#original-host: WinXP Prof SP2 (Build 2600)

Ура! Покопав справку VB5 и немного поимпровизировав, нашла наконец как правильно таскать элементы в дереве. Правда, способ отличается от того что делают при работе с TreeView напрямую, он в стиле Visual Basic, но вроде работает ^_^ Правда, в справке была неточность, но я её исправила.

Dim DragNode As Node
Dim InDrag As Boolean

Private Sub tvTasks_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Debug.Print "tvTasks_MouseDown :: InDrag=" & InDrag
  
  ' Вот это нам не подходит, поскольку к моменту этого события новый
  ' узел ещё не выбран, хоть мы по не му и щёлкнули. Поэтому мы
  ' проверяем что там на самом деле мы нажали...
  'Set DragNode = Me.tvTasks.SelectedItem
  
  InDrag = False
  Set DragNode = Me.tvTasks.HitTest(X, Y)
End Sub

Private Sub tvTasks_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
  If Button = vbLeftButton Then
    Debug.Print "tvTasks_MouseMove"
    If Not DragNode Is Nothing Then
      InDrag = True
      Me.tvTasks.DragIcon = DragNode.CreateDragImage()
      Me.tvTasks.Drag vbBeginDrag
    End If
  End If
End Sub

Private Sub tvTasks_DragOver(Source As Control, X As Single, Y As Single, State As Integer)
  Debug.Print "tvTasks_DragOver"
  If InDrag Then
    Set Me.tvTasks.DropHighlight = Me.tvTasks.HitTest(X, Y)
  End If
End Sub

Private Sub tvTasks_DragDrop(Source As Control, X As Single, Y As Single)
  Debug.Print "tvTasks_DragDrop"
  If Not Me.tvTasks.DropHighlight Is Nothing Then
    If Not Me.tvTasks.DropHighlight Is DragNode Then
      MsgBox """" & DragNode.Text & """ was dropped on """ & _
             Me.tvTasks.DropHighlight.Text & """", vbInformation
    End If
  End If
  
  Set Me.tvTasks.DropHighlight = Nothing
  InDrag = False
End Sub

#music: Need For Speed III: Hot Pursuit\HOMEROCK