[lindachan]

#post-id: 3741-18-36
#original-date: 23.10.2010 Sat
#original-time: 6:36 PM
#original-day:  3741
#original-host: WinXP Prof SP3 (Build 2600)

Мелочи...

Option Explicit

' Declare применены для того чтобы отлавливать ошибки.
Declare Function CreateFile Lib "Kernel32" Alias "CreateFileA" _
                    (ByVal lpFileName As String, _
                     ByVal dwDesiredAccess As Long, _
                     ByVal dwShareMode As Long, _
                     ByVal lpSecurityAttributes As Long, _
                     ByVal dwCreationDistribution As Long, _
                     ByVal dwFlagsAndAttributes As Long, _
                     ByVal hTemplateFile As API_HANDLE) As API_HANDLE

Declare Function DeviceIoControl Lib "Kernel32" _
            (ByVal hDevice As API_HANDLE, _
             ByVal dwIoControlCode As Long, _
             ByRef lpInBuffer As Any, _
             ByVal nInBufferSize As Long, _
             ByRef lpOutBuffer As Any, _
             ByVal nOutBufferSize As Long, _
             ByRef lpBytesReturned As Long, _
             ByRef lpOverlapped As OVERLAPPED) As C_BOOL

Declare Function WriteFileByNum Lib "Kernel32" Alias "WriteFile" _
                    (ByVal hFile As API_HANDLE, _
                     ByRef lpBuffer As Any, _
                     ByVal nNumberOfBytesToWrite As Long, _
                     ByRef lpNumberOfBytesWritten As Long, _
                     ByVal lpOverlapped As Long) As C_BOOL

Declare Function ReadFileByNum Lib "Kernel32" Alias "ReadFile" _
                    (ByVal hFile As API_HANDLE, _
                     ByRef lpBuffer As Any, _
                     ByVal nNumberOfBytesToRead As Long, _
                     ByRef lpNumberOfBytesRead As Long, _
                     ByVal lpOverlapped As Long) As C_BOOL

Type PARTITION_INFORMATION
  StartingOffset As LARGE_INTEGER
  PartitionLength As LARGE_INTEGER
  HiddenSectors As Long
  PartitionNumber As Long
  PartitionType As Byte
  BootIndicator As Byte       ' BOOLEAN == BYTE
  RecognizedPartition As Byte ' BOOLEAN == BYTE
  RewritePartition As Byte    ' BOOLEAN == BYTE
  PAD As Long                 ' Не знаю, откуда оно берётся...
End Type

Type DISK_GEOMETRY
  Cylinders As LARGE_INTEGER
  MediaType As MEDIA_TYPE
  TracksPerCylinder As Long
  SectorsPerTrack As Long
  BytesPerSector As Long
End Type

Const IOCTL_DISK_GET_PARTITION_INFO = &H74004
Const IOCTL_DISK_GET_DRIVE_GEOMETRY = &H70000

Private Const PARTITION_ENTRY_UNUSED = &H0      ' Entry unused
Private Const PARTITION_FAT_12 = &H1            ' 12-bit FAT entries
Private Const PARTITION_XENIX_1 = &H2           ' Xenix
Private Const PARTITION_XENIX_2 = &H3           ' Xenix
Private Const PARTITION_FAT_16 = &H4            ' 16-bit FAT entries
Private Const PARTITION_EXTENDED = &H5          ' Extended partition entry
Private Const PARTITION_HUGE = &H6              ' Huge partition MS-DOS V4
Private Const PARTITION_IFS = &H7               ' IFS Partition
Private Const PARTITION_FAT32 = &HB             ' FAT32
Private Const PARTITION_FAT32_XINT13 = &HC      ' FAT32 using extended int13 services
Private Const PARTITION_XINT13 = &HE            ' Win95 partition using extended int13 services
Private Const PARTITION_XINT13_EXTENDED = &HF   ' Same as type 5 but uses extended int13 services
Private Const PARTITION_PREP = &H41             ' PowerPC Reference Platform (PReP) Boot Partition
Private Const PARTITION_LDM = &H42              ' Logical Disk Manager partition
Private Const PARTITION_UNIX = &H63             ' Unix
Private Const VALID_NTFT = &HC0                 ' NTFT uses high order bits

'====================================================================
Public Function GetPartitionSize(ByVal TargetDrive As BStr) As Double
  Dim hDevice As API_HANDLE
  Dim ShareMode As Long
  Dim DeviceName As BStr
  
  TargetDrive = Left(TargetDrive, 1)
  DeviceName = "\\.\" & TargetDrive & ":"
  ShareMode = FILE_SHARE_READ Or FILE_SHARE_WRITE
  
  hDevice = CreateFile(DeviceName, GENERIC_READ, ShareMode, _
                       0, OPEN_EXISTING, 0, 0)
  If hDevice = INVALID_HANDLE_VALUE Then
    ajpErr.ErrorDisplayAPI Err.LastDllError, , , _
                           DeviceName & CRLFCRLF & "Не удалось открыть " & _
                           "устройство! Эта ошибка не повлияла на диск: " & _
                           "все данные на нём сохранились."
    GetPartitionSize = 0
    Exit Function
  End If
  
  Dim PI As PARTITION_INFORMATION
  Dim OL As OVERLAPPED
  Dim nPI As Long
  Dim RC As Long
  
  RC = DeviceIoControl(hDevice, IOCTL_DISK_GET_PARTITION_INFO, _
                       ByVal 0&, 0, PI.StartingOffset.LowPart, _
                       Len(PI), nPI, OL)
  If RC <> 0 Then
    GetPartitionSize = asLargeIntegerToDouble(PI.PartitionLength)
    
    'MsgBox asFormatByteSizeEx(Size) & CRLF & _
           asFormatInt64(Size) & CRLF & _
           PI.PartitionType
  Else
    ajpErr.ErrorDisplayAPI Err.LastDllError, , , _
                           DeviceName & CRLFCRLF & "Не удалось " & _
                           "получить размер раздела. Эта ошибка " & _
                           "не повлияла на диск: все данные на " & _
                           "нём сохранились."
    GetPartitionSize = 0
  End If
  
  If hDevice <> 0 Then CloseHandle hDevice
End Function

'====================================================================
Public Function GetPhysicalDiskSize(ByVal TargetDrive As BStr) As Double
  Dim hDevice As API_HANDLE
  Dim ShareMode As Long
  Dim DeviceName As BStr
  
  TargetDrive = Left(TargetDrive, 1)
  DeviceName = "\\.\" & TargetDrive & ":"
  ShareMode = FILE_SHARE_READ Or FILE_SHARE_WRITE
  
  hDevice = CreateFile(DeviceName, GENERIC_READ, ShareMode, _
                       0, OPEN_EXISTING, 0, 0)
  If hDevice = INVALID_HANDLE_VALUE Then
    ajpErr.ErrorDisplayAPI Err.LastDllError, , , _
                           DeviceName & CRLFCRLF & "Не удалось открыть " & _
                           "устройство! Эта ошибка не повлияла на диск: " & _
                           "все данные на нём сохранились."
    GetPhysicalDiskSize = 0
    Exit Function
  End If
  
  Dim DG As DISK_GEOMETRY
  Dim OL As OVERLAPPED
  Dim nDG As Long
  Dim RC As Long
  
  RC = DeviceIoControl(hDevice, IOCTL_DISK_GET_DRIVE_GEOMETRY, _
                       ByVal 0&, 0, DG.Cylinders.LowPart, _
                       Len(DG), nDG, OL)
  If RC <> 0 Then
    Dim Size As Double
    
    Size = asLargeIntegerToDouble(DG.Cylinders)
    Size = Size * CDbl(DG.TracksPerCylinder)
    Size = Size * CDbl(DG.SectorsPerTrack)
    Size = Size * CDbl(DG.BytesPerSector)
    
    GetPhysicalDiskSize = Size
    
    'MsgBox asFormatByteSizeEx(Size) & CRLF & _
           asFormatInt64(Size) & CRLF & _
           PI.PartitionType
  Else
    ajpErr.ErrorDisplayAPI Err.LastDllError, , , _
                           DeviceName & CRLFCRLF & "Не удалось " & _
                           "получить размер физического диска. " & _
                           "Эта ошибка не повлияла на диск: все " & _
                           "данные на нём сохранились."
    GetPhysicalDiskSize = 0
  End If
  
  If hDevice <> 0 Then CloseHandle hDevice
End Function

Обе функции принимают букву диска, но одна возвращает размер раздела, навешенного на букву, а вторая - размер всего диска, на котором расположен раздел.

#music: Scooter\Age Of Love\Hit The Drum